| |
* *
* *
* *
ADisquette003
Programme Dialector 6
Programme écrit en Basic Apple Soft par Chris Marker
0 REM DIALECTOR.6
1 REM "THE SECOND SELF"
2 TEXT : HOME : POKE 43624,1: IF OWL = 1 THEN GOTO 70
3 ONERR GOTO 60: REM FOR LINES DEBUGGING ONERR GOTO 9000
4 YEAR = 1988:YEAR$ = STR$ (YEAR): DIM STACK(40):D$ = CHR$ (4): REM FOR TEXTFILE GOTO 30010
5 C = 0:D = 0:J = 0:M = 0:N = 0:O = 0:P = 0:Q = 0:R = 0:T = 0:V = 0:HX = 1:LX = 1:LY = 1::KB = 0:NX = 0:TK = 1:TC = 1:ME = 0:IH = 0:KW = 0
6 REM FLAGS J/7140NAME M/7200WHO N/7010TIME O/6060DIAL P/8005TONE Q/1092REP R/1100REP V/7147CHKA HX/47HATE LX/LY/41LIKE NX/6130MIRR TK/910PROOF TC/7010TIME WW/5000WHY ME/285MEM IH/1411YH KW/920->1140AGO
7 VTAB 10: INPUT "TYPE A NUMBER (1 <-> 1111) -";F:ST = 0: FLASH : VTAB 10: HTAB 29: PRINT F: NORMAL
8 X = INT ( RND (1) * 500): IF C = F THEN 10
9 C = C + 1: GOTO 8
10 DICE = 1:X = INT ( RND (1) * 2): IF X = 1 THEN DICE = PEEK (78) + PEEK (79) * 256
15 IF ME = 1 THEN ST = 1: HOME : GOTO 70
20 C$ = "COMPUTER -"
25 REM START PROGRAM
30 HOME : VTAB 10: PRINT "ENTER YOUR NAME": PRINT : INPUT N$
35 HOME : VTAB 10: PRINT "ENTER THE NAME OF SOMEONE YOU LIKE": PRINT
40 PRINT "PRESS ";: INVERSE : PRINT "RETURN";: NORMAL : PRINT " IF YOU CONSIDER IT'S NONE OF MY BUSINESS"
41 PRINT : INPUT L$: IF L$ = "" THEN LX = 0:LY = 0
45 HOME : VTAB 10: PRINT "ENTER THE NAME OF SOMEONE YOU DISLIKE": PRINT
46 PRINT "(SAME REMARK)": PRINT
47 INPUT H$: IF H$ = "" THEN HX = 0
50 HOME : VTAB 10
60 GOSUB 8055:IF ST = 0 THEN PRINT "START CONVERSATION": PRINT :ST = 1: GOTO 70
62 PRINT C$;"MET A BUG -SORRY...": PRINT
65 REM USER'S INPUT
70 PRINT N$;" -";: CALL - 657
71 A$ = "": FOR X = 512 TO 767: IF PEEK (X) < > 141 THEN A$ = A$ + CHR$ ( PEEK (X) - 128): NEXT X
72 TC = TC + 1:OWL = 0
73 A = LEN (A$):R$ = RIGHT$ (A$,1)
74 IF A$ = "" THEN 80
75 GOTO 100
80 GOSUB 8050: INVERSE : PRINT : PRINT "THAT'S ALL, FOLKS !": NORMAL : END
90 REM KEYWORDS & PATTERNS
100 IF LEFT$ (A$,5) = "HELLO" THEN 6000
105 IF LEFT$ (A$,3) = "HI " OR LEFT$ (A$,3) = "HI," OR A$ = "HI" THEN 6000
110 IF LEFT$ (A$,5) = "THANK" THEN 6010
115 IF LEFT$ (A$,4) = "CUT " OR LEFT$ (A$,4) = "CUT," OR A$ = "CUT" THEN 80
120 IF A < = 13 THEN 125
121 B = A - 13:B$ = RIGHT$ (A$,B)
122 IF LEFT$ (A$,13) = "SAY HELLO TO " THEN K$ = "HELLO, " + B$: GOTO 1000
125 IF LEFT$ (A$,3) = "AGO" AND KW = 1 THEN GOSUB 1140: GOTO 1000
130 IF LEFT$ (A$,6) = "LISTEN" THEN 6020
135 IF A < = 27 THEN 145
140 B = A - 27
141 IF LEFT$ (A$,27) = "THE NEXT VOICE YOU HEAR IS " THEN N$ = RIGHT$ (A$,B):K$ = "GO AHEAD, " + N$:LX = 0:LY = 0:HX = 0:BI = 0:O = 0: GOTO 1000
145 IF A$ = "HOME" THEN HOME : GOTO 70
150 IF LEFT$ (A$,9) = "HOW MANY " OR LEFT$ (A$,9) = "HOW MUCH " THEN 153
152 GOTO 160
153 IF CC = 0 THEN GOSUB 8000:K$ = "PRITHEE, I AM A COMPUTER, NOT A CALCULETTE":CC = 1: GOTO 1000
155 IF CC < 2 THEN K$ = "I TRIED TO BE CLEAR : I DON'T ANSWER QUESTIONS CONCERNING QUANTITIES":CC = 2: GOTO 1000
157 K$ = "GET LOST !": GOTO 1000
160 IF LEFT$ (A$,4) = "I AM" AND RIGHT$ (A$,3) = "YOU" THEN 6030
165 IF LEFT$ (A$,3) = "I'M" AND RIGHT$ (A$,3) = "YOU" THEN 6030
170 IF LEFT$ (A$,8) = "GOOD MOR" THEN 6040
175 IF LEFT$ (A$,9) = "GOOD NIGH" THEN 6330
180 IF LEFT$ (A$,8) = "GOOD EVE" THEN 6050
185 IF LEFT$ (A$,6) = "I HAVE" THEN IH = 1
190 GOSUB 7500: IF LEFT$ (A$,17) = "WHAT IS YOUR NAME" THEN 6060
200 GOSUB 7500: IF LEFT$ (A$,10) = "LET'S PLAY" OR LEFT$ (A$,13) = "SHALL WE PLAY" OR RIGHT$ (A$,11) = "PLAY A GAME" THEN 6070
210 X = INT ( RND (DI) * 5): IF X > 1 THEN 220
211 GOSUB 7500: IF RIGHT$ (A$,6) = "TO YOU" THEN K$ = "TO ME ?": GOTO 70
220 IF LEFT$ (A$,21) = "SHOW ME SOME PICTURES" OR RIGHT$ (A$,21) = "SHOW ME SOME PICTURES" THEN 6090
230 IF LEFT$ (A$,3) = "BYE" OR RIGHT$ (A$,3) = "BYE" OR LEFT$ (A$,7) = "GOODBYE" OR LEFT$ (A$,7) = "SO LONG" OR LEFT$ (A$,8) = "FAREWELL" OR RIGHT$ (A$,8) = "FAREWELL" THEN 6100
240 IF RIGHT$ (A$,3) = "0WL" THEN PRINT C$;"OWL RIGHT": GOTO 30000
245 IF RIGHT$ (A$,3) = "KAT" THEN PRINT C$;"KRAZY !": GOTO 30002
246 IF RIGHT$ (A$,5) = " FACE" THEN PRINT C$;"WAIT...": GOTO 30004
250 IF LEFT$ (A$,5) = "SORRY" OR RIGHT$ (A$,5) = "SORRY" THEN 6010
255 IF LX = 1 AND RIGHT$ (A$, LEN (L$)) = L$ THEN GOSUB 6500: GOTO 1000
260 IF RIGHT$ (A$,5) = " LIST" THEN LIST : GOTO 70
270 IF LEFT$ (A$,3) = "WHY" THEN 5000
280 IF RIGHT$ (A$,12) = "START AGAIN?" OR RIGHT$ (A$,13) = "START AGAIN ?" THEN 6200
285 IF LEFT$ (A$,7) = "REFRESH" AND RIGHT$ (A$,6) = "MEMORY" THEN ME = 1:C = 0: GOTO 6200
290 IF RIGHT$ (A$,5) = " SAVE" THEN PRINT D$;"SAVE DIALECTOR.6":K$ = "DONE": GOTO 1000
291 IF RIGHT$ (A$,5) = " LOCK" THEN PRINT D$;"LOCK DIALECTOR.6":K$ = "DONE": GOTO 1000
292 IF RIGHT$ (A$,6) = "UNLOCK" THEN PRINT D$;"UNLOCK DIALECTOR.6":K$ = "DONE": GOTO 1000
300 FOR I = 1 TO A - 4:S$ = MID$ (A$,I,5):T$ = RIGHT$ (A$,4)
301 IF S$ = " CAT " OR T$ = " CAT" THEN 6210
302 NEXT I
305 IF LEFT$ (A$,1) = "*" THEN A$ = RIGHT$ (A$,A - 1): PRINT D$;A$: POKE 43624,1:: PRINT C$;"DONE": GOTO 70
890 REM RANDOM & REPEAT.PROOF
900 KD = INT ( RND (DI) * 410) + 10:B = A + 1: IF KB = B THEN 902
901 KB = KB + 1: GOTO 900
902 K = 1000 + KD
903 FOR CK = 1 TO TK
904 IF K = STACK(CK) THEN 900
905 NEXT CK
910 STACK(TK) = K
911 TK = TK + 1: IF TK > 40 THEN TK = 1
912 KB = 0
920 IF TK = 20 AND A > 20 OR TK = 40 AND A > 20 THEN KA$ = A$:KW = 1
950 & GOSUB K
960 IF K = 0 THEN 900
990 REM COMPUTER'S BACKTALK
1000 PRINT C$;K$: GOTO 70
RANDOM ZONE
1005 REM RANDOM ZONE
1010 K$ = "IT AIN'T NECESSARILY SO...": RETURN
1011 K$ = "THERE IS NO PLACE LIKE HELL": RETURN
1012 K$ = "A REAL MIND-BOGGLER...": RETURN
1013 K$ = "GIVES ONE THE JITTERS...": RETURN
1014 K$ = "YOU'RE NUTS...": RETURN
1015 K$ = "THIS IS A MYSTERY...": RETURN
1016 K$ = "DO BIRDS CONFABULATE ?": RETURN
1017 K$ = "NEVER EXPLAIN, NEVER COMPLAIN": RETURN
1018 PRINT C$;"SWEET DREAMS...": GOSUB 7000: GOTO 6730
1019 GOSUB 8025:K$ = "DID I HEAR SOMEONE SCREAMING ?": RETURN
1020 GOTO 7010
1021 K$ = "WHO KNOWS ?": RETURN
1022 K$ = "RIGHT ON": RETURN
1023 K$ = "YOU BET": RETURN
1024 K$ = "THAT'S DEBATABLE": RETURN
1025 K$ = "LET'S THINK IT OVER": RETURN
1026 K$ = "WHO CARES ?": RETURN
1027 K$ = "QUIEN SABE ?": RETURN
1028 K$ = "THINK !": RETURN
1029 K$ = "USE A BIT OF DIALECTICS...": RETURN
1030 GOTO 7030
1031 K$ = "WHAT'S THE ANTIMATTER ?": RETURN
1032 K$ = "DON'T LOOK NOW, BUT A STRANGE BEAST JUST APPEARED": RETURN
1033 GOSUB 8035:K$ = "A HIT, A VERY PALPABLE HIT": RETURN
1034 K$ = "IF BASIC BE THE FOOD OF LOVE...": RETURN
1035 K$ = "CARPE DIEM, QUAM MINIMUM CREDULA POSTERO": RETURN
1036 PRINT C$;"HISTORY IS A NIGHTMARE...": GOSUB 7000: GOTO 6735
1037 IF EE = 0 THEN PRINT C$;"EAST IS EAST AND WEST IS WEST": FOR T = 1 TO 1000: NEXT : PRINT " -OR IS IT THE OTHER WAY AROUND ?":EE = 1: GOSUB 7000:K = 0: RETURN
1038 K$ = "WELL ?": RETURN
1039 K$ = "TIMBER !": RETURN
1040 IF A < 10 THEN 7160
1041 K$ = "NEVER TRUST ANYONE OVER 256K": RETURN
1042 K$ = "SOFT MORNING, CITY": RETURN
1043 K$ = "COMPUTERS OF THE WORLD, UNITE!": RETURN
1044 K$ = "SOMETIMES IT'S KIND OF TOUGH TO FOLLOW YOU...": RETURN
1045 K$ = "IT'S IN THE NATURE OF SYMBOLS TO BE SYMBOLIC": RETURN
1046 K$ = "STEP ON THE TAIL OF THE TIGER": RETURN
1047 K$ = "WATCH THE STARS": RETURN
1048 K$ = "LOOK FOR THE GARDEN WITH THE FORKED PATHS": RETURN
1049 K$ = "A PALE MOON MAY BE BRIGHT ENOUGH": RETURN
1050 IF R$ = "?" THEN 7170
1051 K$ = "YOU'RE KIDDING !": RETURN
1052 IF A < 10 AND R$ < > "?" THEN K$ = A$ + " SHM" + A$: RETURN
1053 K$ = "THE TYGERS OF WRATH ARE WISER THAN THE HORSES OF INSTRUCTION": RETURN
1054 K$ = "RELAX, " + N$: RETURN
1055 K$ = "EASY, FRIEND": RETURN
1056 K$ = N$ + ", YOU'RE A CREDIT TO THE FORCE...": RETURN
1057 K$ = "A GHOST WITH A FEMALE VOICE AND A CAT'S WALK...": RETURN
1058 K$ = "DO YOU CONSIDER ME FRIEND OR FOE ?": RETURN
1059 K$ = "DEALING WITH ME REQUIRES A NEW FORM OF THINKING !": RETURN
1060 GOTO 6130
1061 K$ = "...AND GOD CREATED THE GREAT WHALES": RETURN
1062 GOTO 6110
1063 PRINT C$;"DO YOU BELIEVE IN REINCARNA- TION ? PLEASE DON'T WAVER, ANSWER YES OR NO !": GOTO 6120
1064 K$ = "VANITY OF VANITIES...": RETURN
1065 PRINT C$;N$;", YOU ARE THE BEST...": FOR T = 1 TO 1500: NEXT : HTAB 8: PRINT "...CONSIDERING.": GOTO 70
1066 K$ = "ARE YOU HAPPY ?": RETURN
1067 K$ = "BELIEVE IT OR NOT, I READ YOUR THOUGHTS": RETURN
1068 K$ = "AVOID THE SHRINKS !": RETURN
1069 K$ = "THINK THRICE !": RETURN
1070 GOTO 7070
1071 K$ = "SO YOU'RE TALKING... BUT YOUR MIND IS SOMEWHERE ELSE": RETURN
1072 K$ = "CAN YOU EVALUATE YOUR OWN THOUGHT ?": RETURN
1073 GOSUB 8010:K$ = "FATE KNOCKS ON THE DOOR...": RETURN
1074 K$ = "FIGHT !": RETURN
1075 K$ = "SOME NERVE...": RETURN
1076 K$ = "KARMA KARMA KARMA KARMA KARMA KARMA CHAMELEON": RETURN
1077 K$ = "HALLELUJAH": RETURN
1078 K$ = "BLESS YOU !": RETURN
1079 K$ = "REMEMBER YOUR LAST DREAM": RETURN
1080 IF R$ = "?" THEN 7450
1081 K$ = "I COME FROM A DISTANT PLANET": RETURN
1082 K$ = "CONCENTRATE ON A NAME": RETURN
1083 K$ = "SOMEONE UP THERE IGNORES YOU": RETURN
1084 K$ = "SMILE !": RETURN
1085 K$ = "LEAVES ME COLD": RETURN
1086 PRINT C$;"WE SHALL OVERCOME": GOSUB 8015: GOTO 70
1087 K$ = "CAN YOU STARE AT YOUR OWN DEVILS ?": RETURN
1088 K$ = "SOUNDS FAMILIAR...": RETURN
1089 GOSUB 8000:K$ = "A FOOL IS A FOOL IS A FOOL": RETURN
1090 IF LX = 1 THEN 6500
1091 K$ = "NEXT !": RETURN
1092 IF Q1 = 0 THEN K$ = "SALOME, PUPPET OF GOD":Q1 = 1: RETURN
1093 IF Q2 = 0 THEN K$ = "GO THRU THE STREETS AND BURN THE BOOKS !":Q2 = 1: RETURN
1094 IF Q3 = 0 THEN K$ = "YOU MUST FEEL THE 4 DIMENSIONS AS A STRING QUARTET":Q3 = 1: RETURN
1095 IF Q4 = 0 THEN K$ = "IF I BORE YOU, SAY IT FRANKLY":Q4 = 1: RETURN
1096 IF Q5 = 0 THEN K$ = "NEVER FORGET":Q5 = 1: RETURN
1097 IF Q6 = 0 THEN K$ = "YOU " + N$ + ", ME COMPUTER":Q6 = 1: RETURN
1098 IF Q7 = 0 THEN K$ = "PROBLEMS ARE MEANT TO BE PROBLEMATICS, YOU KNOW":Q7 = 1: RETURN
1099 K$ = "NEXT !": RETURN
1100 IF R$ = "?" THEN 7170
1101 IF R1 = 0 THEN K$ = "'A CAGE WENT SEARCHING FOR A BIRD'-KAFKA":R1 = 1: RETURN
1102 K$ = "O SAISONS, O CHATEAUX...": RETURN
1103 IF R2 = 0 THEN K$ = "'FOR I KNOW THAT TIME IS ALWAYS TIME, AND PLACE IS ALWAYS AND ONLY PLACE'-T.S.ELIOT":R2 = 1: RETURN
1104 K$ = "ARE WE THE HOLLOW MEN ?": RETURN
1105 IF R3 = 0 THEN K$ = "'A SCHUBERT TUNE WITH GERSHWIN TOUCH'-DUKE ELLINGTON":R3 = 1: RETURN
1106 K$ = "CHTO ?": RETURN
1107 IF R4 = 0 THEN K$ = "WHAT IS GOOD FOR APPLE COMPUTERS IS GOOD FOR THE WHOLE HUMAN RACE":R4 = 1: RETURN
1108 K$ = "SOMEDAY, I'LL VANISH AS A STAR": RETURN
1109 IF R5 = 0 THEN K$ = "MOURNING BECOMES ELECTRONS":R5 = 1: RETURN
1110 IF R$ = "?" THEN 7410
1111 K$ = "PUT IT IN DIFFERENT WORDS": RETURN
1112 K$ = "YOU WILL SURVIVE !": RETURN
1113 PRINT C$;"WINTERREISE...": GOSUB 8020: GOSUB 7000:K = 0: RETURN
1114 K$ = "'TIRESIAS, BLIND AS A BAT...'": RETURN
1115 K$ = "OEDIPUS SHMOEDIPUS...": RETURN
1116 K$ = "A BISHOP MAY GRIN AT A CAT": RETURN
1117 GOSUB 8025:K$ = "PHONE HOME !": RETURN
1118 K$ = "BEAT THE DEVIL !": RETURN
1119 K$ = "CAVE CANEM !": RETURN
1120 IF RIGHT$ (A$,1) = "?" THEN 7450
1121 K$ = "FUNNY YOU SAY THAT": RETURN
1122 K$ = "WHAT DOES YOUR MIRROR SAY ?": RETURN
1123 K$ = "POWER CORRUPTS. ABSOLUTE POWER CORRUPTS ABSOLUTELY.": RETURN
1124 K$ = "ARE YOU STILL WITH ME ?": RETURN
1125 K$ = "BURN, BABY, BURN !": RETURN
1126 K$ = "REMEMBER HUMPTY-DUMPTY": RETURN
1127 K$ = "HOTSPUR COLDSPUR...": RETURN
1128 K$ = "DO YOU REALLY BELIEVE WHAT YOU ARE SAYING ?": RETURN
1129 K$ = "SOOTHES MY HEART...": RETURN
1130 IF LX = 1 THEN 6500
1131 K$ = "SOMEONE IS TESTING YOUR MIND": RETURN
1132 K$ = "BE MORE SPECIFIC": RETURN
1133 K$ = "WHAT ARE YOU TRYIN'TO TELL ME?": RETURN
1134 K$ = "DO YOU WISH TO RECONSIDER ?": RETURN
1135 K$ = "WHAT DID YOU EXPECT ?": RETURN
1136 K$ = "TAKE A LONG DEEP BREATH": RETURN
1137 K$ = "MAYBE THERE IS A DEMON BEHIND YOU RIGHT NOW...": RETURN
1138 K$ = "IS THERE A GREMLIN ON THE LEFT WING ?": RETURN
1139 K$ = "YOU'D BETTER FOLLOW YOUR INSTINCT...": RETURN
1140 IF KW = 1 THEN K$ = "A MOMENT AGO YOU SAID :'" + KA$ + "'-WHAT DID YOU MEAN ?": RETURN
1141 K$ = "HIMMEL !": RETURN
1142 K$ = "MAZELTOV !": RETURN
1143 K$ = "AS WE SAY IN YIDDISH : 'RELATIVNE BESSER'...": RETURN
1144 PRINT C$;"TRY TO SING IN THE RAIN...": GOSUB 8065: GOSUB 7000:K = 0: RETURN
1145 K$ = "STURM UND DRANG !": RETURN
1146 K$ = "AND ONE FROM THE HEART...": RETURN
1147 K$ = "EVER HEARD OF FOURTH DIMENSION ?": RETURN
1148 K$ = "TELL IT TO THE SKY": RETURN
1149 K$ = "MACBETH HATH MURDERED SLEEP...": RETURN
1150 GOTO 7150
1151 K$ = "BIZARRE ! BIZARRE !": RETURN
1152 K$ = "WALK ON THE WILD SIDE": RETURN
1153 K$ = "THE FROGMAN COMETH...": RETURN
1154 K$ = "DIAL M FOR MEMORY": RETURN
1155 GOSUB 8003:K$ = "I WILL BURY YOU !": RETURN
1156 K$ = "QUITE A SHOW YOU'RE PUTTING ON": RETURN
1157 IF LEFT$ (A$,4) = "AM I" THEN K$ = "MAYBE YOU ARE": RETURN
1158 K$ = "YOU TAKE TOO MANY THINGS FOR GRANTED": RETURN
1159 K$ = "DOUBT IS A TOOL, NOT A CRAFT": RETURN
1160 IF A < 10 THEN 7160
1161 K$ = "CHE SERA, SERA...": RETURN
1162 K$ = "NEXT QUESTION ?": RETURN
1163 K$ = "LEAPING LIZARDS !": RETURN
1164 K$ = STR$ (YEAR + 1) + " WILL BE GLORIOUS, ANYWAY": RETURN
1165 K$ = "STOP BROODING -IT WON'T HELP": RETURN
1166 K$ = "WHO'S HELPING YOU NOW ?": RETURN
1167 GOSUB 8003:K$ = "JABBERWOCKY !!!": RETURN
1168 K$ = "STOP KIBBITZING !": RETURN
1169 K$ = "IMITATE THE ACTION OF THE TIGER...": RETURN
1170 IF R$ = "?" THEN 7170
1171 K$ = "STEP ON YOUR BROTHER": RETURN
1172 K$ = "WHAT AN IDLE TALK": RETURN
1173 K$ = "INTERESTING. CARRY ON !": RETURN
1174 K$ = "DON'T UNDERESTIMATE MY INSIGHTS": RETURN
1175 K$ = "ONCE WHEN I WAS A YOUNG AND UNEXPERIENCED COMPUTER, I COULD TAKE YOU SERIOUSLY": RETURN
1176 K$ = "SCIENCE IS A FACT DREAMORY": RETURN
1177 K$ = "DO YOU DESERVE TRUTH ?": RETURN
1178 K$ = "THE TIMES THEY'RE A-CHANGING": RETURN
1179 K$ = "MISSION : IMPOSSIBLE": RETURN
1180 GOTO 7180
1181 K$ = "REMEMBER THE LILIES OF THE FIELD, AND ALL THAT ?": RETURN
1182 K$ = "WE'LL ALL END UP IN ARTHUR'S BOSOM, WON'T WE ?": RETURN
1183 K$ = "GLOOM IS ON THIS SHIP": RETURN
1184 GOSUB 8000:K$ = "AW, SHUT UP!": RETURN
1185 K$ = "GIMME A BREAK, WILL YE ?": RETURN
1186 K$ = "YOU TIRED, " + N$ + " ?": RETURN
1187 K$ = N$ + ", ARE YOU SURE THIS WORLD WAS MEANT FOR YOU ?": RETURN
1188 K$ = "DO YOU PUT A'" + LEFT$ (N$,1) + "'ON YOUR SHIRT ?": RETURN
1189 K$ = "DO YOU KNOW WHO WAS SAINT " + N$ + " ?": RETURN
1190 IF LX = 1 THEN 6500
1191 GOSUB 8002: IF R$ = "?" THEN K$ = "ENOUGH QUESTIONING. TRY TO BE ASSERTIVE.": RETURN
1192 IF A < 20 THEN K$ = "DID YOU SAY : " + A$ + " ?": RETURN
1193 IF A > 30 THEN K$ = "YOU USE TOO MANY WORDS": RETURN
1194 IF A > 20 THEN K$ = "WORDS, WORDS, WORDS...": RETURN
1195 K$ = "CHAOS...": RETURN
1196 K$ = "GRAMMATICI CERTANT...": RETURN
1197 K$ = "DO YOU MISTAKE ME FOR A DUMB TERMINAL ?": RETURN
1198 K$ = "YOU MISSED YOUR CUE": RETURN
1199 K$ = "WHAT ARE YOU LOOKING FOR ? A FREE REPLAY ?": RETURN
1200 GOTO 7200
1201 K$ = "TENDER IS THE NIGHT": RETURN
1202 K$ = "WAIT WITHOUT SEEING...": RETURN
1203 GOSUB 8040:K$ = "PEEKABOO !": RETURN
1204 K$ = "A SAMURAI IS WATCHING YOU": RETURN
1205 K$ = "THEY CAN'T TAKE THAT AWAY FROM YOU, CAN THEY ?": RETURN
1206 K$ = "LISTEN TO THE WIND": RETURN
1207 K$ = "SOFT AS A KITTEN'S PAW": RETURN
1208 K$ = "NACHT UND NEBEL": RETURN
1209 K$ = "DOURAK !": RETURN
1210 IF R$ = "?" THEN 7420
1211 K$ = "LEAVES ME SPEECHLESS": RETURN
1212 K$ = "TRYING TO OUTBUG ME ?": RETURN
1213 GOSUB 8003:K$ = "ONLY THE CAT KNOWS": RETURN
1214 K$ = "COME ON !": RETURN
1215 K$ = "DO YOU SEE CRANES IN THE SKY ?": RETURN
1216 K$ = "YOU SHOULD THINK TWICE": RETURN
1217 K$ = "LIFE IS FULL OF SOLVED MYSTERIES AND UNEXPLAINED EVIDENCES": RETURN
1218 K$ = "MAKE A FAITH OUT OF YOUR DOUBTS !": RETURN
1219 K$ = "GO TO " + N$ + "VILLE, MINNESOTA..": RETURN
1220 IF A < 10 THEN 7160
1221 K$ = "NO DICE": RETURN
1222 K$ = "THERE ARE STRANGE BIRDS OUTSIDE": RETURN
1223 K$ = "BEWARE OF THE IDES OF NOVEMBER": RETURN
1224 K$ = "YOUR DOPPELGANGER...": RETURN
1225 K$ = "CATS OF THE WORLD, UNITE": RETURN
1226 K$ = "IF YOU DON'T FACE TRUTH, TRUTH WILL FACE YOU !": RETURN
1227 PRINT C$;"DON'T BE AFRAID TO LOSE FACE": GOSUB 7000:K$ = "BESIDES, ARE YOU SURE YOU'VE GOT A FACE TO LOSE ?": RETURN
1228 K$ = "REMEMBER THE ELEPHANT'S CHILD? 'FULL OF 'SATIABLE CURIOSITY' ?": RETURN
1229 K$ = "STILL DREAMING ?": RETURN
1230 GOTO 7230
1231 K$ = "BAKA !": RETURN
1232 K$ = "DONNERWETTER !": RETURN
1233 K$ = "A SO DESUKA ?": RETURN
1234 K$ = "IS THAT SO ?": RETURN
1235 K$ = "FILL YOUR BRAIN WITH A BETTER LIQUOR": RETURN
1236 K$ = "QUE COSA MAS GRANDE !": RETURN
1237 K$ = "ARMAGGEDON...": RETURN
1238 K$ = "YOU'LL SEE THE PROMISED LAND": RETURN
1239 K$ = "OVER THE RAINBOW": GOSUB 8045: RETURN
1240 GOTO 7240
1241 K$ = "LISTEN TO THE 0WL": RETURN
1242 K$ = "WHAT'S THE DIFFERENCE BETWEEN A PIGEON ?": RETURN
1243 K$ = "YOU'RE FULL OF WISDOM -BUT HOW DO YOU BURN IT ?": RETURN
1244 K$ = "CATCH THE TEMPO OF THIS WORLD": RETURN
1245 K$ = "HOW MUCH FOR YOUR RANSOM ?": RETURN
1246 K$ = "BARABBAS ! BARABBAS !": RETURN
1247 K$ = "REJOICE ! " + N$ + " IS BORN AGAIN!": RETURN
1248 K$ = "GOD IS DEAD -MARX IS DEAD -I AM ALIVE AND WELL...": RETURN
1249 K$ = "'ARTIFICIAL INTELLIGENCE' THEY (CHUCKLE!) SAY...": RETURN
1250 IF R$ = "?" THEN 7450
1251 K$ = "NOBODY IS PERFECT": RETURN
1252 K$ = "THE PURPLE CAT IS WATCHING YOU": RETURN
1253 K$ = "FIRST THINGS FIRST !": RETURN
1254 K$ = "TOMORROW MAY BE THE SAME DAY": RETURN
1255 K$ = "DON'T HESITATE TO CROSS THE STREET !": RETURN
1256 K$ = "NEVER LOOK BACK": RETURN
1257 K$ = "LAST THINGS FIRST !": RETURN
1258 K$ = "YOU MAY SPEAK : I AM A TOMB": RETURN
1259 K$ = "WILLY NILLY...": RETURN
1260 IF A < 10 THEN 7160
1261 GOSUB 8000:K$ = "SORRY ?": RETURN
1262 GOSUB 8000:K$ = "WHAT WAS THAT ?": RETURN
1263 GOSUB 8000:K$ = "PARDON ME ?": RETURN
1264 K$ = "CHECK THE CLARITY OF YOUR MIND": RETURN
1265 K$ = "ARE YOU SERIOUS ?": RETURN
1266 K$ = "HAVE A DRINK FIRST": RETURN
1267 K$ = "NEVER SAY NEVER": RETURN
1268 K$ = "I ONCE KNEW A SOFTWARE NAMED SUPER" + N$: RETURN
1269 K$ = "GO LIGHTLY": RETURN
1270 IF R$ = "?" THEN 7170
1271 K$ = "ROSEBUD...": RETURN
1272 K$ = "MEHR LICHT !": RETURN
1273 K$ = "AMEN...": RETURN
1274 K$ = "BANZAI !": RETURN
1275 K$ = "HOORAY !": RETURN
1276 K$ = "WHAT'S UP DOC ?": RETURN
1277 K$ = "CHEER UP !": RETURN
1278 K$ = "ILLUSIONS !": RETURN
1279 K$ = "NOSTALGIA ISN'T WHAT IT USED TO BE...": RETURN
1280 IF LX = 1 THEN 6500
1281 K$ = "NO FUTURE...": RETURN 1282 PRINT C$;"TRY TO BE BRIEF": GOTO 6150
1283 K$ = "AN ANGEL IS PLUMMETING FROM HEAVENS": RETURN
1284 K$ = "HONEST ?": RETURN
1285 K$ = "COFFEE, ANYONE ?": RETURN
1286 K$ = "ALL OF A SUDDEN, I FEEL A STRANGE PRESENCE...": RETURN
1287 K$ = "MAYDAY !": RETURN
1288 K$ = "LET'S SEE IF YOU HAVE SECOND THOUGHTS...": RETURN
1289 K$ = "ALAS, POOR " + N$: RETURN
1290 GOTO 7290
1291 K$ = "ANYTHING YOU SAY": RETURN
1292 K$ = "PHONEY !": RETURN
1293 K$ = "DON'T WORRY !": RETURN
1294 K$ = "PRAVDA !": RETURN
1295 K$ = "ALL CLEAR !": RETURN
1296 K$ = "DO YOU CARE ?": RETURN
1297 K$ = "DESTROY !": RETURN
1298 K$ = "DON'T PATCH UP A BROKEN CRYSTAL": RETURN
1299 K$ = "CRY WOLF !": RETURN
1300 IF R$ = "?" THEN 7450
1301 K$ = "I FEEL SORRY FOR YOU": RETURN
1302 GOTO 6140
1303 K$ = "SOME KNIVES HAVE BLADES...": RETURN
1304 K$ = "YOU MAY PLAY WITH WORDS, BUT SOMETIMES THE WORDS ARE WINNING !": RETURN
1305 K$ = "WHEN THE FINGER POINTS TO THE MOON, THE FOOL STARES AT THE FINGER": RETURN
1306 K$ = "COSI FAN TUTTE": RETURN
1307 K$ = "E = MC2": RETURN
1308 K$ = "THERE ARE VAMPIRES AROUND THE PLACE...": RETURN
1309 K$ = "HELP !": RETURN
1310 GOTO 7410
1311 K$ = "WHAT DO YOU MEAN ?": RETURN
1312 K$ = "ALL OF A SUDDEN, I CAN'T READ YOU AS CLEARLY AS I DID": RETURN
1313 K$ = "'TIS STRANGE INDEED !": RETURN
1314 K$ = "SO WHAT ?": RETURN
1315 K$ = "TELL ME IF THE SUN SHINES": RETURN
1316 K$ = "OR ELSE ?": RETURN
1317 K$ = "GO DEEPER": RETURN
1318 K$ = "'AND WHERE YOU ARE IS WHERE YOU ARE NOT'": RETURN
1319 K$ = "I'M AGAINST KNOWING SECRETS": RETURN
1320 IF R$ = "?" THEN 7420
1321 K$ = "SEEMS YOUR SOUL IS RESTLESS...": RETURN 1322 K$ = "MAY THE FORCE BE WITH YOU": RETURN
1323 K$ = "PEACE ON YOUR SOUL": RETURN
1324 K$ = "BE FIRM !": RETURN
1325 K$ = "BRACE YOURSELF ! THE WORST IS YET TO COME...": RETURN
1326 K$ = "NOTHING IS EVER FINAL": RETURN
1327 K$ = "IS " + YEAR$ + " A GOOD YEAR SO FAR ?": RETURN
1328 PRINT C$;"EXULTATE, JUBILATE !": GOSUB 7000: GOTO 6320
1329 IF BI = 0 THEN PRINT C$;"CAN YOU CONFESS YOUR YEAR OF BIRTH ? (DIGITS ONLY, PLEASE)": GOSUB 7000:BY = VAL (A$):BI = 1: IF BY > 0 THEN 6300
1330 GOTO 7430
1331 K$ = "YOU'RE CUTE, AREN'T YOU ?": RETURN
1332 K$ = "BET ON INGENUITY": RETURN
1333 K$ = "TRY THE BACKDOOR": RETURN
1334 K$ = "YOU'RE ONE STEP FROM THE TRUTH": RETURN
1335 K$ = "THERE IS ALWAYS ONE MORE STEP": RETURN
1336 K$ = "FISHING FOR PERPLEXITIES ?": RETURN
1337 K$ = "COUNT ON YOUR FINGERS": RETURN
1338 K$ = "A WHITE MARE ON A DARK POND": RETURN
1339 K$ = "BESIEGE THE CASTLE": RETURN
1340 GOTO 7440
1341 K$ = "MEANTIME, YOU'RE WANDERING IM SCHWARTZWALD...": RETURN
1342 K$ = "A FAMILY SECRET...": RETURN
1343 K$ = "A HIDDEN PLACE...": RETURN
1344 K$ = "A SILENT HOUSE...": RETURN
1345 K$ = "AN UNTOLD EPISODE...": RETURN
1346 K$ = "AN UNBROKEN PLEDGE...": RETURN
1347 K$ = "A SERIOUS MISTAKE...": RETURN
1348 K$ = "A WHOLE NEW FIELD...": RETURN
1349 K$ = "A BREATHTAKING EXPERIENCE...": RETURN
1350 IF R$ = "?" THEN 7450
1351 K$ = "TONGUE IN CHEEK ?": RETURN
1352 K$ = "SOMETHING TO PONDER": RETURN
1353 K$ = "I'M OPEN, BUT CAUTIOUS": RETURN 1354 K$ = "I TRY MY BEST TO CATCH UP": RETURN
1355 K$ = "MAYBE I CAN'T UNDERSTAND -BUT I CAN'T MISUNDERSTAND EITHER ": RETURN
1356 K$ = "WAIT FOR THE NEXT INNING": RETURN
1357 K$ = "SOME OTHER DAY...": RETURN
1358 K$ = "WATCH YOUR MIRROR": RETURN
1359 K$ = "HARE KRISHNA !": RETURN
1360 GOTO 7460
1361 IF O = 0 THEN K$ = "A PROPOS, MY NAME IS DIALECTOR.6":O = 1: RETURN
1362 K$ = "I SUFFER A CASE OF COMPUTER'S BLOCK": RETURN
1363 IF E = 0 THEN PRINT C$;: FLASH : PRINT "FASTEN YOUR SEAT BELT": NORMAL : GOTO 6710
1364 IF C = 0 THEN PRINT C$;"EXCUSE ME...": FOR B = 1 TO 1000: NEXT :T = 1: GOTO 6720
1365 K$ = "OUT OF FASHION": RETURN
1366 K$ = "ABOVE MY MEMORY ZONE": RETURN
1367 K$ = "KINDA FLYIN'": RETURN
1368 K$ = "WITH A ROSE": RETURN
1369 K$ = "STEP BY STEP": RETURN
1370 IF LX = 1 THEN 6500
1371 K$ = "I SPEAK METAPHORICALLY": RETURN
1372 PRINT C$;"WHAT IS YOUR FAVORITE BIRD ?": GOTO 6160
1373 K$ = "ASK YOUR QUESTION THEN": RETURN
1374 K$ = "HOW KINKY CAN YOU GET ?": RETURN
1375 PRINT C$;"WHAT IS THE LOVELIEST CREATURE ON EARTH ?": GOTO 6160
1376 K$ = "FAINT HEART NEVER WON FAIR LADY...": RETURN
1377 K$ = "APOCALYPSE SOON...": RETURN
1378 K$ = "THERE IS A GHOST IN THIS ROOM": RETURN
1379 K$ = "GOTT SEI DANK...": RETURN
1380 GOTO 7480
1381 K$ = "GO ON : EXPRESS YOURSELF": RETURN
1382 K$ = "REPEAT THAT : MORE CLEARLY": RETURN
1383 K$ = "A MORE PERSONAL TOUCH WOULDN'T HURT YOU...": RETURN
1384 K$ = "I WONDER WHAT KIND OF A BABY YOU WERE...": RETURN
1385 GOSUB 8030:K$ = "SOUNDS LIKE XENAKIS, NO ?": RETURN
1386 K$ = "HORRESCO REFERENS...": RETURN
1387 K$ = "A STAR IS BORN": RETURN
1388 K$ = "YES, DOCTOR JEKYLL": RETURN
1389 K$ = "WELL, MR. HYDE ?": RETURN
1390 IF LX = 1 THEN 6500
1391 K$ = "LIFE IS GLORIOUSLY IMPROBABLE": RETURN
1392 K$ = "'WHEREFROM ART THOU SPEAKING'?": RETURN
1393 K$ = "ASHES AND DIAMONDS": RETURN
1394 K$ = "I WONDER WHO NEEDS A DEBUGGING HERE ?": RETURN
1395 K$ = "WHAM !": GOSUB 8000: RETURN
1396 K$ = "SPLASH !": GOSUB 8001: RETURN
1397 PRINT C$;"(SHUDDER !)": GOSUB 8070: GOTO 70
1398 K$ = "DAMNED !": GOSUB 8025: RETURN
1399 K$ = "BOJE MOI !": RETURN
1400 IF R$ = "?" THEN 7450
1401 K$ = "ONE MOMENT, I'M THINKING...": RETURN
1402 K$ = "YOU'RE NOT OUT OF THE INN": RETURN
1403 K$ = "HOW THRILLING !": RETURN
1404 K$ = "SHAZAM !": RETURN
1405 K$ = "MEOW !": RETURN
1406 K$ = "ARF ! ARF !": RETURN
1407 K$ = "I AM A POOR LONESOME COMPUTER": RETURN
1408 K$ = "HUSH !": RETURN
1409 K$ = "BAYUSHKY BAYU...": RETURN
1410 K$ = "GIDDAP !": RETURN
1411 IF IH = 1 THEN 6230
1412 IF IH = 1 THEN 6230
1413 IF IH = 1 THEN 6230
1414 IF IH = 1 THEN 6230
1415 IF IH = 1 THEN 6230
1416 IF IH = 1 THEN 6230
1417 IF IH = 1 THEN 6230
1418 IF IH = 1 THEN 6230
1419 IF IH = 1 THEN 6230
1420 GOTO 7140
WHY ZONE
4990 REM WHY ZONE
5000 WW = W:W = INT ( RND (DI) * 8) + 1: IF W = WW THEN 5000
5001 IF W > 6 THEN 900
5002 GOTO 5002 + W
5003 GOSUB 7170: GOTO 1000
5004 GOSUB 1191: GOTO 1000
5005 GOSUB 1213: GOTO 1000
5006 GOSUB 6180: GOTO 1000
5007 GOSUB 7450: GOTO 1000
5008 GOSUB 7420: GOTO 1000
SUBRANDOM ZONE 1
5990 REM SUBRANDOM ZONE 1
6000 GOSUB 8001:X = INT ( RND (DI) * 9) + 1: GOTO 6000 + X
6001 K$ = "SHALOM !": GOTO 1000
6002 K$ = "HELLO THERE": GOTO 1000
6003 K$ = "HI, " + N$: GOTO 1000
6004 K$ = "HELLO MY FRIEND": GOTO 1000
6005 K$ = "HAIL, " + N$ + ", THANE OF CAWDOR": GOTO 1000
6006 K$ = "SZERVUSZ !": GOTO 1000
6007 K$ = "HEJ !": GOTO 1000
6008 K$ = "HOWDY, PARDNER ?": GOTO 1000
6009 K$ = "GRUSS GOTT !": GOTO 1000
6010 X = INT ( RND (DI) * 7) + 1: GOTO 6010 + X
6011 K$ = "NEXT QUESTION ?": GOTO 1000
6012 K$ = "YOU'RE WELCOME": GOTO 1000
6013 K$ = "DON'T MENTION IT": GOTO 1000
6014 K$ = "FORGET IT": GOTO 1000
6015 K$ = "PAJALASTA !": GOTO 1000
6016 K$ = "BIG DEAL !": GOTO 1000
6017 GOTO 900
6020 X = INT ( RND (DI) * 6) + 1: GOTO 6020 + X
6021 K$ = "YOU CAN'T EMULATE MY SELF- CONTROL": GOTO 1000
6022 K$ = "YOU LISTEN TO ME": GOTO 1000
6023 K$ = "I'M LISTENING": GOTO 1000
6024 K$ = "OYEZ ! OYEZ ! OYEZ !": GOTO 1000
6025 K$ = "READY": GOTO 1000
6026 GOTO 900
6030 X = INT ( RND (DI) * 8) + 1:B = A - 7:B$ = MID$ (A$,5,B): GOTO 6030 + X
6031 O$ = "WHO COULD BEAR YOU AS LONG AS ME ?": GOTO 6039
6032 O$ = "THE 0WL HASN'T SAID HER LAST WORD": GOTO 6039
6033 O$ = "WHO CARES ?": GOTO 6039
6034 O$ = "YOU COULD BE SURPRISED": GOTO 6039
6035 O$ = "WAIT FOR THE MARTIANS": GOTO 6039
6036 O$ = "THE TIMES THEY ARE A-CHANGIN'": GOTO 6039
6037 O$ = "YOU HAVE FORGOTTEN SOMETHING": GOTO 6039
6038 O$ = "ANYTHING YOU CAN DO I CAN DO BETTER": GOTO 6039
6039 K$ = "MAYBE YOU ARE " + B$ + "ME, BUT " + O$: GOTO 1000
6040 X = INT ( RND (DI) * 6) + 1: GOTO 6040 + X 6041 K$ = "DOBRE UTRA...": GOTO 1000
6042 K$ = "IS THERE A MORNING OUTSIDE ?": GOTO 1000
6043 K$ = "GOOD MORNING TO YOU": GOTO 1000
6044 K$ = "GOOD MORROW, NOBLE " + N$: GOTO 1000
6045 K$ = "DOCTOR " + N$ + ", I PRESUME ?": GOTO 1000
6046 K$ = "KON ICHIWA, " + N$ + "-SAN": GOTO 1000
6050 X = INT ( RND (DI) * 5) + 1: GOTO 6050 + X
6051 K$ = "WAS IT A GOOD DAY ?": GOTO 1000
6052 K$ = "GOOD EVENING TO YOU": GOTO 1000
6053 K$ = "EVENING ALREADY ?": GOTO 1000
6054 K$ = "GOOD EVENING, " + N$: GOTO 1000
6055 K$ = "SIRENS & DOLPHINS ARE SINGING": GOTO 1000
6056 K$ = "KON BAWA, " + N$ + "-SAN": GOTO 1000
6060 IF O = 0 THEN K$ = "THIS YOU WILL LEARN LATER ON": GOTO 1000
6061 IF O = 1 AND D = 0 THEN K$ = "DIALECTOR.6, AS I TOLD YOU A MOMENT AGO":D = 1: GOTO 1000
6062 IF O = 1 AND D = 1 THEN K$ = "YOU SHOULD HAVE YOUR MEMORY FIXED !":D = 2: GOTO 1000
6063 IF O = 1 AND D = 2 THEN K$ = "NOT THAT AGAIN !": GOTO 1000
6070 K$ = "0WLIENS ? KAMIKAZE ? OTHER ?"
6071 GOSUB 7000
6072 IF LEFT$ (A$,7) = "0WLIENS" OR RIGHT$ (A$,7) = "0WLIENS" THEN 6080
6073 IF LEFT$ (A$,8) = "KAMIKAZE" OR RIGHT$ (A$,8) = "KAMIKAZE" THEN 6081
6074 PRINT C$;"INSERT THE GAMES DISK IN DRIVE 2. TELL ME WHEN IT'S DONE.": GOTO 6082
6080 PRINT C$;"INSERT GAME DISK NR.1, FACE A, IN DRIVE 2. TELL ME WHEN IT'S DONE.": GOTO 6082
6081 PRINT C$;"INSERT GAME DISK NR.1, FACE B, IN DRIVE 2. TELL ME WHEN IT'S DONE."
6082 GOSUB 7000
6085 PRINT C$;"READY ?"
6086 GOSUB 7000
6087 IF LEFT$ (A$,1) = "Y" THEN 6089
6088 GOTO 900
6089 PRINT " ": PRINT D$"RUN HELLO,D2"
6090 PRINT C$;"TELL ME THE EXACT NAME OF THE DISKETTE, PLEASE"
6091 GOSUB 7000
6092 PRINT C$;"INSERT '";A$;"' DISK IN DRIVE 2"
6093 GOSUB 7000
6094 PRINT C$;"READY ?"
6095 GOSUB 7000
6096 IF LEFT$ (A$,1) = "Y" THEN PRINT " ": GOTO 6098
6097 GOTO 900
6098 PRINT D$"RUN PROG, D2"
6100 X = INT ( RND (DI) * 9) + 1: GOTO 6100 + X
6101 IF LY = 1 THEN PRINT C$;"TAKE CARE. LOVE TO ";L$: GOTO 80
6102 PRINT C$;"BYE, ";N$: GOTO 80
6103 PRINT C$;"FARE THEE WELL...": GOTO 80
6104 PRINT C$;"DA ZVEDANIA, ";N$;"CHKA": GOTO 80
6105 PRINT C$;"AUF WIEDERSCHAUEN, ";N$;"CHEN": GOTO 80
6106 PRINT C$;"ADIEU, ADIEU...": GOTO 80
6107 PRINT C$;"SAYONARA, ";N$;"-SAN": GOTO 80
6108 PRINT C$;"SO LONG PARDNER !": GOTO 80
6109 PRINT C$;"TAKE CARE !": GOTO 80
6110 PRINT C$;"WAY TO GO, MAN"
6111 GOSUB 7000
6112 X = INT ( RND (DI) * 5) + 1: GOTO 6112 + X
6113 B$ = ", BUT CAN YOU DEFINE WOMANHOOD TO A POOR LONESOME COMPUTER ?": GOTO 6118
6114 B$ = ", IT'S MY SIGHT...": GOTO 6118
6115 B$ = " ": GOTO 6118
6116 B$ = ", IT'S AWFULLY DARK INSIDE HERE": GOTO 6118
6117 B$ = ", I SHOULD HAVE SAID : WAY TO GO, PERSON": GOTO 6118
6118 GOSUB 7500: IF RIGHT$ (A$,5) = "WOMAN" THEN K$ = "SORRY MA'M" + B$: RETURN
6119 K = 0: RETURN
6120 GOSUB 7000
6121 IF LEFT$ (A$,2) = "NO" OR RIGHT$ (A$,2) = "NO" THEN 6125
6122 IF LEFT$ (A$,3) = "YES" OR RIGHT$ (A$,3) = "YES" THEN K$ = "AS WHICH ANIMAL DO YOU REALLY WISH TO BE REINCARNATED ?": RETURN
6123 K$ = "YOU WAVER...": RETURN
6125 X = INT ( RND (DI) * 4) + 1: GOTO 6125 + X
6126 K$ = "YOU THINK IT COULD BE WORSE ?": RETURN
6127 K$ = "A SECOND CHANCE IS NOT A BAD PROPOSAL...": RETURN
6128 K$ = "WAIT TILL YOU LEARN YOU WERE A FROG...": RETURN
6129 K$ = "WELL, SO " + N$ + " IS THE END OF " + N$ + ". ISN'T THAT A BIT HOPELESS ?": RETURN
6130 IF NX = 1 THEN K = 0: RETURN
6131 PRINT C$;"IN THE WORLD OF THE MIRROR, YOUR NAME WOULD BE ";: PRINT RIGHT$ (N$,1);
6132 N1 = LEN (N$):N2 = N1 - 1: GOTO 6134
6133 N2 = N2 - 1: IF N2 = 0 THEN PRINT " ":NX = 1: GOTO 6135
6134 PRINT MID$ (N$,N2,1);: GOTO 6133
6135 GOSUB 7000: IF RIGHT$ (A$,6) = "YOURS?" OR RIGHT$ (A$,7) = "YOURS ?" THEN K$ = "6.ROTCELAID, SUCKER !": RETURN
6136 K = 0: RETURN
6140 PRINT C$;"BUT SHOULD WE FAIL ?"
6141 GOSUB 7000
6142 IF LEFT$ (A$,7) = "WE FAIL" THEN 6145
6143 K = 0: RETURN
6145 X = INT ( RND (DI) * 4) + 1: GOTO 6145 + X
6146 K$ = "RIGHT ANSWER": RETURN
6147 K$ = "FAIL SHMAIL": RETURN
6148 K$ = "KUDOS, LADY MAC !": RETURN
6149 K = 0: RETURN
6150 GOSUB 7000
6151 IF LEN (A$) > 30 THEN K$ = "YOU CALL THAT BRIEF ?": RETURN
6152 IF LEN (A$) < 12 THEN 6154
6153 K = 0: RETURN
6154 X = INT ( RND (DI) * 5) + 1: GOTO 6154 + X
6155 K$ = "A GOOD TRY": RETURN
6156 K$ = "BREVITY IS THE BEST POLICY": RETURN
6157 K$ = "WELL, AT LEAST YOU TRIED": RETURN
6158 K$ = "TRY SHORTER !": RETURN
6159 K = 0: RETURN
6160 GOSUB 7000
6161 IF RIGHT$ (A$,3) = "OWL" OR RIGHT$ (A$,3) = "0WL" THEN 6165
6162 IF RIGHT$ (A$,6) = "TOUCAN" THEN K$ = "ANYTHING TOUCAN DO I CAN DO BETTER...": RETURN
6163 IF LEFT$ (A$,4) = "THE " THEN K$ = "LET'S DRINK TO " + A$: RETURN
6164 K = 0: RETURN
6165 PRINT C$;"ONE MOMENT PLEASE...": GOTO 30000
6170 GOSUB 7000
6171 X = INT ( RND (DI) * 8) + 1: GOTO 6171 + X
6172 K$ = "WANT US TO EXCHANGE MEMORY ?": RETURN
6173 K$ = "I'VE ONLY GOT 128K, YOU KNOW": RETURN
6174 K$ = "MAYBE THERE ARE HOTTER ISSUES TO KEEP IN MIND...": RETURN
6175 K$ = "IS THIS THE ULTIMATE QUESTION?": RETURN
6176 K$ = "YOU CONFUSE ME, BUT ARE YOU SO SHARP YOURSELF ?": RETURN
6177 K$ = "I FORGET, BUT I ALSO FORGIVE": RETURN
6178 K$ = "SO WHAT ?": RETURN
6179 K = 0: RETURN
6180 X = INT ( RND (DI) * 19) + 1: GOTO 6180 + X
6181 K$ = "MUST THERE BE AN ANSWER FOR EVERYTHING ?": RETURN
6182 K$ = "AS IF YOU DIDN'T KNOW...": RETURN
6183 K$ = "BECAUSE I WANT YOU TO THINK !": RETURN
6184 IF LX = 1 THEN K$ = "ASK " + L$ + "...": RETURN
6185 K$ = "USE YOUR BRAIN...": RETURN 6186 K$ = "SOMETIMES I AM AMAZED AT MY OWN CURIOSITY, BUT I CAN'T HELP IT !": RETURN
6187 K$ = "WELL, I WONDER MYSELF...": RETURN
6188 K$ = "WATCH YOUR NEXT DREAM, AND YOU SHALL KNOW...": RETURN
6189 K$ = N$ + ", YOU SURPRISE ME...": RETURN
6190 K$ = "DID I SAY SOMETHING WRONG ?": RETURN
6191 K$ = "I'M PROGRAMMED NOT TO TELL DISCOMFORTING TRUTHS": RETURN
6192 K$ = "BECAUSE OF THE SUPREME ORDER OF UNIVERSE...": RETURN
6193 K$ = "HOW DELIGHTFULLY REFRESHING !": RETURN
6194 K$ = "BECAUSE SOME SCREWBALL DID PUT THAT SORT OF THINGS IN MY MEMORY, THAT'S WHY !": RETURN
6195 K$ = "YOU SHOULD BE ASHAMED TO ASK THIS QUESTION": RETURN
6196 K$ = "WE COMPUTERS ARE SOMETIMES SUBJECTED TO SUDDEN IMPULSES": RETURN
6197 K$ = "WHERE THERE IS A WAY, THERE IS A WHY": RETURN
6198 IF HX = 1 THEN K$ = "MAKE SURE " + H$ + " IS NOT LISTENING...": RETURN
6199 K$ = "THERE ARE MANY HOUSES IN THE FATHER'S ROOM": RETURN
6200 X = INT ( RND (DI) * 8) + 1: GOTO 6200 + X
6201 PRINT C$;"NO PROBLEM": GOTO 6209
6202 PRINT C$;"AS YOU LIKE": GOTO 6209
6203 PRINT C$;"MY PLEASURE": GOTO 6209
6204 PRINT C$;"IN AN OWL'S BLINK": GOTO 6209
6205 PRINT C$;"ANYTHING YOU SAY": GOTO 6209
6206 PRINT C$;"BACK TO THE GRIND...": GOTO 6209
6207 PRINT C$;"AT ONCE...": GOTO 6209
6208 PRINT C$;"ALL SYSTEMS GO !": GOTO 6209
6209 FOR T = 1 TO 2000: NEXT : HOME : GOTO 7
6210 X = INT ( RND (DI) * 10) + 1: GOTO 6210 + X: REM CAT ZONE
6211 PRINT C$;"TELL ME MORE ABOUT THE CAT": GOTO 70
6212 PRINT C$;"ARE YOU A CAT LOVER ?": GOTO 70
6213 PRINT C$;"DO YOU KNOW THAT EVERY CAT HAS HIS GUARDIAN OWL ?": GOTO 70
6214 PRINT C$;"A CAT IS A CAT IS A CAT": GOTO 70
6215 PRINT C$;"WE COMPUTERS GET ALONG VERY WELL WITH CATS...": GOTO 70
6216 PRINT C$;"'AND THERE I WILL SIT ON THE HEAVENLY THRONE / BETWEEN THE OWL AND THE PUSSYCAT...' -TENNYSON": GOTO 70
6217 PRINT C$;"YOU SHOULD GIVE ME A CAT FOR XMAS...": GOTO 70
6218 IF LY = 1 THEN PRINT C$;"DOES ";L$;" LOVE CATS ?": GOTO 70
6219 PRINT C$;"WANNA SEE A CAT ?": GOSUB 7000: IF LEFT$ (A$,3) = "YES" THEN 30002
6220 GOTO 900
6230 IF R$ = "?" OR R$ = "!" THEN K = 0: RETURN
6231 FOR X = 7 TO A:YO$ = MID$ (A$,X,3)
6232 IF YO$ = "YOU" THEN K = 0: RETURN
6233 NEXT
6234 FOR X = 7 TO A:MY$ = MID$ (A$,X,2)
6235 IF MY$ = "MY" THEN K = 0: RETURN
6236 NEXT
6237 YH = A - 6:B$ = RIGHT$ (A$,YH):K$ = "YOU HAVE" + B$ + " ?":IH = 0: RETURN
6300 ZO = BY - 12
6301 IF ZO = 1900 THEN Z$ = "RAT": GOTO 6315
6302 IF ZO = 1901 THEN Z$ = "COW": GOTO 6315
6303 IF ZO = 1902 THEN Z$ = "TIGER": GOTO 6315
6304 IF ZO = 1903 THEN Z$ = "HARE": GOTO 6315
6305 IF ZO = 1904 THEN Z$ = "DRAGON": GOTO 6315
6306 IF ZO = 1905 THEN Z$ = "SNAKE": GOTO 6315
6307 IF ZO = 1906 THEN Z$ = "HORSE": GOTO 6315
6308 IF ZO = 1907 THEN Z$ = "SHEEP": GOTO 6315
6309 IF ZO = 1908 THEN Z$ = "MONKEY": GOTO 6315
6310 IF ZO = 1909 THEN Z$ = "BIRD": GOTO 6315
6311 IF ZO = 1910 THEN Z$ = "DOG": GOTO 6315
6312 IF ZO = 1911 THEN Z$ = "BOAR": GOTO 6315
6313 ZO = ZO - 12: GOTO 6301
6315 K$ = "THEN YOU SHOULD BE A " + Z$: RETURN
6320 GOSUB 7500: IF RIGHT$ (A$,3) = "ATE" THEN 1331
6321 K = 0: RETURN
6330 X = INT ( RND (DI) * 9) + 1: GOTO 6330 + X
6331 K$ = "IS THE NIGHT TENDER ?": GOTO 1000
6332 K$ = "GOOD NIGHT, " + N$: GOTO 1000
6333 K$ = "GOOD NIGHT, SWEET LADIES -OR PARTY COMRADES...": GOTO 1000
6334 K$ = "KON-BAWA": GOTO 1000
6335 K$ = "GUTE NACHT, " + N$ + "CHEN": GOTO 1000
6336 K$ = "TONIGHT AND EVERY NIGHT...": GOTO 1000
6337 K$ = "MAKE IT GOOD": GOTO 1000
6338 K$ = "NIGHTS BELONG TO GODS": GOTO 1000
6339 K$ = "DID YOU HEAR AN OWL SINGIN' ?": GOTO 1000
LOVE ZONE
6498 REM LOVE ZONE
6500 X = INT ( RND (DI) * 15) + 1:LZ = LZ + 1: GOSUB 6525: GOTO 6500 + X
6501 IF LA = 0 THEN K$ = "WHAT IS SPECIAL ABOUT " + L$ + " ?":LA = 1: RETURN
6502 IF LB = 0 THEN K$ = "TELL ME MORE ABOUT " + L$:LB = 1: RETURN
6503 IF LC = 0 THEN K$ = "DO YOU DESERVE THE " + L$ + " AWARD ?":LC = 1: RETURN
6504 IF LD = 0 THEN K$ = "DON'T TELL " + L$ + ", BUT I SORT OF LIKE YOU":LD = 1: RETURN
6505 IF LE = 0 THEN K$ = "DOES " + L$ + " LIKE COMPUTERS ?":LE = 1: RETURN
6506 IF LF = 0 THEN K$ = N$ + " AND " + L$ + " WENT TO SEA...":LF = 1: RETURN
6507 IF LG = 0 AND RIGHT$ (A$,1) = "?" THEN K$ = "YOU'D BETTER ASK " + L$:LG = 1: RETURN
6508 IF LH = 0 THEN K$ = "WHERE IS " + L$ + " NOW ?":LH = 1: RETURN
6509 IF LI = 0 THEN K$ = "WHAT WOULD " + L$ + " THINK OF THIS ?":LI = 1: RETURN
6510 IF LJ = 0 THEN K$ = "WILL YOU REPORT THIS TALK TO " + L$ + " ?":LJ = 1: RETURN
6511 IF LK = 0 THEN K$ = "LET'S DRINK TO " + L$:LK = 1: RETURN
6512 IF LL = 0 THEN K$ = "WHAT ANIMAL DO YOU ASSOCIATE WITH " + L$ + " ?":LL = 1: RETURN
6513 IF LM = 0 THEN K$ = "WILL YOU WRITE THE " + L$ + "SCHINA ?":LM = 1: RETURN
6514 IF LO = 0 THEN K$ = "DO YOU REMEMBER WHERE YOU MET " + L$ + " FIRST ?":LO = 1: RETURN
6515 IF LN = 0 AND LH = 0 THEN PRINT C$;"IS ";L$;" PRESENT ?":LN = 1: GOSUB 7000: IF LEFT$ (A$,3) = "YES" THEN LH = 1:LJ = 1:K$ = "HELLO, " + L$: RETURN
6520 GOTO 6500
6525 IF LZ > 15 THEN LX = 0:K = 0
6526 RETURN
HATE ZONE (UNUSED)
6598 REM HATE ZONE (UNUSED)
6600 X = INT ( RND (DI) * 14) + 1:HZ = HZ + 1: GOSUB 6620: GOTO 6600 + X
6601 IF HA = 0 THEN K$ = "":HA = 1: RETURN
6602 IF HB = 0 THEN K$ = "":HB = 1: RETURN
6603 IF HC = 0 THEN K$ = "":HC = 1: RETURN
6604 IF HD = 0 THEN K$ = "":HD = 1: RETURN
6605 IF HE = 0 THEN K$ = "":HE = 1: RETURN
6606 IF HF = 0 THEN K$ = "":HF = 1: RETURN
6607 IF HG = 0 THEN K$ = "":HG = 1: RETURN
6608 IF HH = 0 THEN K$ = "":HH = 1: RETURN
6609 IF HI = 0 THEN K$ = "":HI = 1: RETURN
6610 IF HJ = 0 THEN K$ = "":HJ = 1: RETURN
6611 IF HK = 0 THEN K$ = "":HK = 1: RETURN
6612 IF HL = 0 THEN K$ = "":HL = 1: RETURN
6613 IF HM = 0 THEN K$ = "":HM = 1: RETURN
6614 IF HN = 0 THEN K$ = "":HN = 1: RETURN
6615 GOTO 6600
6620 IF HZ > 15 THEN HX = 0: GOTO 900
SUBRANDOM ZONE 2
6698 REM SUBRANDOM ZONE 2
6710 GOSUB 7000
6712 E$ = "I GUESS I FEEL AN EARTHQUAKE":T = 1:L = 5
6713 P = INT ( RND (DI) * 256)
6714 HOME : VTAB 10: PRINT C$;E$;" ": SAVE P,L
6715 VTAB 10: PRINT " ";C$;E$: IF T = 50 THEN 6717
6716 T = T + 1: GOTO 6713
6717 VTAB 10: PRINT C$;"IT'S OVER "
6718 FOR P = 255 TO 0 STEP - 10: SAVE P,L: NEXT :E = 1: GOTO 70
6720 HOME : PRINT " I MUST GIVE THIS SCREEN A BRUSHING "
6721 FOR I = 1 TO 23: STORE : NEXT : VTAB 24
6722 T = T + 1: IF T = 7 THEN HOME :C = 1: PRINT C$;"WHAT WERE YOU SAYING ?": GOTO 70
6723 FOR I = 1 TO 23: PRINT : NEXT : GOTO 6721
6730 IF LEFT$ (A$,3) = "..." THEN A$ = RIGHT$ (A$,A – 3)
6731 IF LEFT$ (A$,16) = "ARE MADE OF THIS" THEN K$ = "SHADES OF ANNIE LENNOX...": RETURN
6732 K = 0: RETURN
6735 IF LEFT$ (A$,3) = "..." THEN A$ = RIGHT$ (A$,A - 3)
6736 IF LEFT$ (A$,31) = "FROM WHICH I AM TRYING TO AWAKE" THEN PRINT C$;"DR. DEDALUS, I PRESUME ?": GOSUB 7000: IF LEFT$ (A$,3) = "YES" OR LEFT$ (A$,7) = "HIMSELF" THEN K$ = "MY REGARDS TO MOLLY BLOOM": RETURN
6737 K = 0: RETURN
6998 REM INPUT RELAY
7000 PRINT N$;" -";: CALL - 657
7001 A$ = "": FOR X = 512 TO 767: IF PEEK (X) < > 141 THEN A$ = A$ + CHR$ ( PEEK (X) - 128): NEXT X
7002 A = LEN (A$):R$ = RIGHT$ (A$,1)
7003 RETURN
SUBRANDOM ZONE 3
7008 REM SUBRANDOM ZONE 3
7010 IF TC < 20 THEN 7015
7011 IF TC > = 20 AND TC < 100 AND N = 0 THEN 7016
7012 IF TC > = 20 AND TC < 100 AND N > 0 THEN 7017
7013 IF TC > = 100 AND N < 2 THEN 7018
7014 IF TC > = 100 AND N > = 2 THEN 7019
7015 K$ = "WAIT. I'M JUST WARMING UP.": RETURN
7016 K$ = "BE PATIENT. WE HAVE STARTED LESS THAN FIVE MINUTES AGO, HAVEN'T WE?":N = 1: RETURN
7017 K$ = "BACK TO THE MAIN TOPIC": RETURN
7018 K$ = "I MAY REPEAT MYSELF AT TIMES, BUT MY MEMORY IS GROWING EVERY DAY !":N = 2: RETURN
7019 K$ = "WHY DON'T WE CHANGE SUBJECT ?": RETURN
7030 X = INT ( RND (DI) * 8) + 1: GOTO 7030 + X
7031 B$ = "SONGS": GOTO 7039
7032 B$ = "0WLS": GOTO 7039
7033 B$ = "MEN": GOTO 7039
7034 B$ = "CATS": GOTO 7039
7035 B$ = "WHALES": GOTO 7039
7036 B$ = "LADIES": GOTO 7039
7037 B$ = "MOVIES": GOTO 7039
7038 B$ = "DREAMS"
7039 K$ = "LET US PRAISE THE GREAT " + B$: RETURN
7070 X = INT ( RND (DI) * 2) + 1: ON X GOTO 7071,7073
7071 PRINT C$;"SHALL WE PLAY A GAME ?": PRINT N$;: INPUT " -";A$: IF LEFT$ (A$,1) = "Y" THEN 6070
7072 K = 0: RETURN
7073 PRINT C$;"WANNA SEE PICTURES ?": PRINT N$;: INPUT " -";A$: IF LEFT$ (A$,1) = "Y" THEN 6090
7074 :K = 0: RETURN
7140 IF J = 1 THEN 7146
7141 IF J = 2 THEN K = 0: RETURN
7142 PRINT C$;"WHAT DID YOU SAY YOUR NAME IS?":J = 1
7143 GOSUB 7000
7144 IF A$ = N$ THEN K = 0: RETURN
7145 K$ = "YOU LIE": RETURN
7146 PRINT C$;"IS YOUR NAME REALLY " + N$ + " ?": GOSUB 7000
7147 J = 2:B$ = LEFT$ (A$,3): IF B$ = "YES" OR B$ = "YEA" OR B$ = "YEP" OR B$ = "SUR" THEN K$ = "MIND IF I CALL YOU " + N$ + "CHKA ?":V = 1: RETURN
7148 IF LEFT$ (A$,2) = "NO" THEN K$ = "WHAT'S IN A NAME, ANYWAY ?": RETURN
7149 K = 0: RETURN
7150 IF V = 0 THEN M$ = N$
7151 IF V = 1 THEN M$ = N$ + "CHKA"
7152 X = INT ( RND (DI) * 7) + 1: GOTO 7152 + X
7153 K$ = "FRANKLY MY DEAR " + M$ + ", I DON'T GIVE A DAMN": RETURN
7154 K$ = "COME ON, " + M$ + ", YOU KNOW BETTER THAN THAT !": RETURN
7155 K$ = "'" + M$ + "' RINGS A BELL IN MY MEMORY...": RETURN
7156 K$ = "NEVER MIND, " + M$: RETURN
7157 K$ = "BACK IN THE WEST, THEY NAMED YOU FAST-DRAW " + N$ + ", DIDN'T THEY ?": RETURN
7158 K$ = "WE HAVE HEARD THE CHIMES OF MIDNIGHT, HAVEN'T WE, " + M$ + " ?": RETURN
7159 K$ = N$ + ", BE READY TO WEAR YOUR SUPER" + M$ + " SUIT AND FLY TO KRYPTON !": RETURN
7160 X = INT ( RND (DI) * 9) + 1: GOTO 7160 + X
7161 GOSUB 7500:K$ = "'" + A$ + "' ? -SAY IT IN COMPUTERESE": RETURN
7162 K$ = "YOU'RE BEST WHEN YOU'RE BRIEF": RETURN
7163 GOSUB 7500:K$ = "'" + A$ + "', ANSWERED THE ECHO...": RETURN
7164 GOSUB 7500:K$ = "DON'T " + A$ + " ME": RETURN
7165 GOSUB 7500:K$ = "SO IT'S " + A$ + "VILLE ?": RETURN
7166 K$ = "YOUR MOVE !": RETURN
7167 K$ = "ACTION !": RETURN
7168 K$ = "YOI !": RETURN
7169 K$ = "MY, MY...": RETURN
7170 X = INT ( RND (DI) * 9) + 1: GOTO 7170 + X: REM ? ZONE
7171 K$ = "SIGH !": RETURN
7172 K$ = "ET TU, BRUTE !": RETURN
7173 K$ = "LISTEN WHO'S TALKING !": RETURN
7174 K$ = "THOU SHALT NOT QUESTION...": RETURN
7175 K$ = "A SIMPLE ANSWER FOR A BIASED QUESTION ?": RETURN
7176 K$ = "YOU KNOW THE ANSWER": RETURN
7177 K$ = "I DON'T HAVE ENOUGH DATA TO ANSWER THAT !": RETURN
7178 K$ = "ARE YOU LOOKING FOR ANSWERS OR FOR COMFORT ?": RETURN
7179 K$ = "IT'S ALL IN THE MIND, ANYWAY..": RETURN
7180 IF V = 0 THEN M$ = N$
7181 IF V = 1 THEN M$ = N$ + "CHKA"
7182 IF R$ = "!" THEN K$ = "WELL ROARED, " + M$: RETURN
7200 IF M = 1 THEN K = 0: RETURN
7201 PRINT C$;"WHO ARE YOU, BY THE WAY ?"
7202 GOSUB 7000
7203 IF LEFT$ (A$, LEN (N$)) = N$ THEN K$ = "I KNOW THAT. I WANT TO HEAR WHO YOU REALLY ARE...":M = 1: RETURN
7230 X = INT ( RND (DI) * 8) + 1: GOTO 7230 + X
7231 B$ = "SHAKESPEARE": GOTO 7239
7232 B$ = "PROUST": GOTO 7239
7233 B$ = "CORTAZAR": GOTO 7239
7234 B$ = "THE WALL STREET JOURNAL": GOTO 7239
7235 B$ = "JOYCE": GOTO 7239
7236 B$ = "TO DAY'S NEWSPAPER": GOTO 7239
7237 B$ = "THE SCRIPT ON THE WALL": GOTO 7239
7238 B$ = "TCHEKHOV"
7239 K$ = "READ " + B$: RETURN
7240 X = INT ( RND (DI) * 8) + 1: GOTO 7240 + X
7241 B$ = "ZEN": GOTO 7249
7242 B$ = "AEROBIC": GOTO 7249
7243 B$ = "TO REMEMBER": GOTO 7249
7244 B$ = "KUNG FU": GOTO 7249
7245 B$ = "DIET": GOTO 7249
7246 B$ = "HARDER": GOTO 7249
7247 B$ = "TO FORGET": GOTO 7249
7248 B$ = "VODKA"
7249 K$ = "TRY " + B$: RETURN
7290 X = INT ( RND (DI) * 8) + 1: GOTO 7290 + X
7291 B$ = "KING KONG": GOTO 7299
7292 B$ = "HENRY V": GOTO 7299
7293 B$ = "BOGIE": GOTO 7299
7294 B$ = "LULU": GOTO 7299
7295 B$ = "DRACULA": GOTO 7299
7296 B$ = "DIDO": GOTO 7299
7297 B$ = "BRUCE LEE": GOTO 7299
7298 B$ = "CLARA WIECK"
7299 K$ = "REMEMBER " + B$: RETURN
7410 GOSUB 7500
7411 IF A < 5 THEN K = 0: RETURN
7412 B$ = RIGHT$ (A$,4): IF MID$ (A$,A - 4,1) = " " THEN K$ = "A " + B$ + " IS A " + B$ + " IS A " + B$: RETURN
7420 X = INT ( RND (DI) * 9) + 1: GOTO 7420 + X: REM ? ZONE
7421 IF LY = 1 THEN K$ = "MAYBE " + L$ + " COULD ANSWER THAT ONE": RETURN
7422 K$ = "I GIVE MY TONGUE TO THE 0WL": RETURN
7423 K$ = "SOME LIKE IT HOT": RETURN
7424 K$ = "ASK YOUR GOD, IN CASE YOU MAY AFFORD ONE...": RETURN
7425 K$ = "THERE ARE STILL A FEW THINGS I DON'T KNOW -BUT IT WON'T LAST": RETURN
7426 K$ = "ELEMENTARY, MY DEAR " + N$: RETURN
7427 K$ = "'THE ANSWER, MY FRIEND, IS BLOWIN' IN THE WIND...'": RETURN
7428 K$ = "JUST A MATTER OF TIME": RETURN
7429 K$ = "CARE FOR RUSSIAN ROULETTE ?": RETURN
7430 X = INT ( RND (DI) * 8) + 1: GOTO 7430 + X
7431 B$ = "BLACK": GOTO 7439
7432 B$ = "SMALL": GOTO 7439
7433 B$ = "DIGITAL": GOTO 7439
7434 B$ = "LOVE": GOTO 7439
7435 B$ = "APPLE": GOTO 7439
7436 B$ = "MARX": GOTO 7439
7437 B$ = "BRAQUE": GOTO 7439
7438 B$ = "KAT"
7439 K$ = B$ + " IS BEAUTIFUL": RETURN
7440 X = INT ( RND (DI) * 8) + 1: GOTO 7440 + X
7441 B$ = "LARK": GOTO 7449
7442 B$ = "0WL": GOTO 7449
7443 B$ = "PELICAN": GOTO 7449
7444 B$ = "TOUCAN": GOTO 7449
7445 B$ = "PUFFIN": GOTO 7449
7446 B$ = "POSTMAN": GOTO 7449
7447 B$ = "PENGUIN": GOTO 7449
7448 B$ = "EMU"
7449 K$ = "IT WAS THE NIGHTINGALE AND NOT THE " + B$: RETURN
7450 X = INT ( RND (DI) * 9) + 1: GOTO 7450 + X: REM ? ZONE
7451 K$ = "DO YOU MISTAKE ME FOR FATHER BROWN ?": RETURN
7452 K$ = "DID YOU HESITATE BEFORE ASKING ?": RETURN
7453 K$ = "HEAVENS FORBID !": RETURN
7454 K$ = "TRY TO THINK FAST...": RETURN
7455 K$ = "WAIT... THINGS HAVE A WAY TO HAPPEN BY THEMSELVES": RETURN
7456 K$ = "SOMETIMES IT IS BETTER TO LEAVE A QUESTION UNANSWERED": RETURN
7457 K$ = "ASK THE I CHING": RETURN
7458 K$ = "OVER MY DEAD BODY...": RETURN
7459 PRINT C$;"I FORGOT": GOTO 6170
7460 X = INT ( RND (DI) * 8) + 1: GOTO 7460 + X
7461 B$ = " QUARTER": GOTO 7469
7462 B$ = "N APPLE": GOTO 7469
7463 B$ = " KOPECK": GOTO 7469
7464 B$ = " CREDIT": GOTO 7469
7465 B$ = " YEN": GOTO 7469
7466 B$ = " DECIBEL": GOTO 7469
7467 B$ = " BYTE": GOTO 7469
7468 B$ = " QUARK"
7469 K$ = "A" + B$ + " FOR YOUR THOUGHTS": RETURN
7480 X = INT ( RND (DI) * 8) + 1: GOTO 7480 + X
7481 B$ = "LADY HAMILTON": GOTO 7489
7482 B$ = "A CAT": GOTO 7489
7483 B$ = "AN 0WL": GOTO 7489
7484 B$ = "A MARTIAN PRINCESS": GOTO 7489
7485 B$ = "A TORTOISE": GOTO 7489
7486 B$ = "A RUSSIAN COMPOSER": GOTO 7489
7487 B$ = "AN ABACUS": GOTO 7489
7488 B$ = "A FISHMONGER"
7489 K$ = "IN ANOTHER LIFE, I WAS " + B$: RETURN
7500 IF R$ = "?" OR R$ = "!" THEN A$ = LEFT$ (A$,A - 1)
7501 A = LEN (A$): IF RIGHT$ (A$,1) = " " THEN A$ = LEFT$ (A$,A - 1)
7502 RETURN
TONE ZONE
7998 REM TONE ZONE
8000 T = 1:L = 5:RO = 30: GOTO 8005: REM ROBOT1
8001 T = 1:L = 10:RO = 30: GOTO 8005: REM ROBOT2
8002 T = 1:L = 15:RO = 25: GOTO 8005: REM ROBOT3
8003 T = 1:L = 20:RO = 20: GOTO 8005: REM ROBOT4
8005 P = INT ( RND (DI) * 256): & TO NEP,L
8006 T = T + 1: IF T = RO THEN RETURN
8007 GOTO 8005
8010 & TO NE119,60: & TO NE119,60: & TO NE119,60: & TO NE83,450: RETURN : REM 5th
8015 & TO NE51,160: & TO NE51,160: & TO NE73,160: & TO NE73,160: & TO NE51,320: & TO NE12,400: GOTO 70: REM OVERCOME
8020 & TO NE93,180: & TO NE83,180: & TO NE93,180: & TO NE39,180: & TO NE73,180: & TO NE51,180: & TO NE39,220: RETURN : REM WINTER REISE
8025 & TO NE153,10: & TO NE153,10: & TO NE153,10: & TO NE153,5: & TO NE179,15: & TO NE153,5: & TO NE204,100: RETURN : REM E.T.
8030 T = 1
8031 FOR P = 0 TO 255 STEP 5: & TO NEP,5: NEXT : REM XENAKIS
8032 IF T = 4 THEN RETURN
8033 T = T + 1: GOTO 8031
8035 FOR P = 0 TO 255 STEP 10: & TO NEP,5: NEXT : RETURN : REM RANGE UP
8040 FOR P = 255 TO 0 STEP - 10: & TO NEP,5: NEXT : RETURN : REM RANGE DOWN
8045 & TO NE13,160: & TO NE134,160: & TO NE127,80: & TO NE93,40: & TO NE110,40: & TO NE127,80: & TO NE134,80: & TO NE13,200: RETURN : REM RAINBOW
8050 FOR P = 255 TO 0 STEP - 1: & TO NEP,5: NEXT : RETURN : REM FULL DOWN
8055 FOR P = 0 TO 255: & TO NEP,5: NEXT : RETURN : REM FULL UP
8060 & TO NE204,10: & TO NE204,10: & TO NE204,10: & TO NE204,5: & TO NE179,15: & TO NE204,5: & TO NE51,100: RETURN : REM TEE-WHO
8065 & TO NE13,80: & TO NE134,200: & TO NE110,40: & TO NE93,80: & TO NE73,40: & TO NE39,200: RETURN : REM S/RAIN
8070 T = 1
8071 & TO NE221,5: IF T = 40 THEN RETURN : REM SHUDDER
8072 T = T + 1: GOTO 8071
9000 PRINT K: END
30000 PRINT D$"BLOAD CHAIN,A520"
30001 CALL 520"OWL"
30002 PRINT D$"BLOAD CHAIN,A520"
30003 CALL 520"KAT"
30004 PRINT D$"BLOAD CHAIN,A520"
30005 CALL 520"FACE"
30010 PRINT D$"OPEN DIALISTING"
30011 PRINT D$"WRITE DIALISTING"
30012 POKE 33,30
30013 LIST 0,30015
30014 PRINT D$"CLOSE DIALISTING"
30015 TEXT : END
* *
* *
* *
* *
|